[BETA] Diskuzní fórum Elektro Bastlírny

Kód: Vybrat vše

/*
  file: test_pwm.ino
*/

// pwm_1khz_set_pwm_duty(0);
//
void pwm_1khz_set_pwm_duty( uint8_t value)
{
  if (value < 125)
  {
    OCR1A = value;
  }
  else
  {
    OCR1A = (125 - 1);
  }
}

// pwm_1khz_setup_oc1a_pb1_IO9();
//
// Phase and Frequency correct PWM mode x8
// TOP is 125
// duty is 0
// prescaler is 64
// enable pin as output
void pwm_1khz_setup_oc1a_pb1_IO9( void)
{
  TCCR1A = 0;
  TCCR1B = 0;
  //
  // WGM: 0b1000, mode: 0x8,
  // COM1A:0b10, clear output on compare match when upcounting
  //
  TCCR1A = _BV(COM1A1);

  // ICR1
  ICR1 = (125);

  // OCR1A
  OCR1A = (0);

  // CS: 0b011, prescaler: 64
  //
  TCCR1B = _BV(WGM13) | (0b011 << CS10);

  // OC1A is PB1 is IO9
  DDRB |= _BV(PB1);
}


void setup() {
  // initialize digital pin LED_BUILTIN as an output.
  pinMode(LED_BUILTIN, OUTPUT);
  Serial.begin(9600);           //  setup serial
  pwm_1khz_setup_oc1a_pb1_IO9();
}


void loop() {
  
  digitalWrite(LED_BUILTIN, HIGH);   // turn the LED on (HIGH is the voltage level)
  delay(1000);                       // wait for a second
  digitalWrite(LED_BUILTIN, LOW);    // turn the LED off by making the voltage LOW
  delay(1000);                       // wait for a second

  uint8_t i = 0;
  do
  {
    pwm_1khz_set_pwm_duty(i);
    Serial.println(i);          // debug value
    delay(200);
    i = i + 1;
  }
  while (i < 125);
}